# Maintainer: SpepS <dreamspepser at yahoo dot it>

pkgname=ladish-git
_pkg="${pkgname%-git}"
pkgver=20111005
pkgrel=1
pkgdesc="A session management system for JACK applications on GNU/Linux."
arch=("i686" "x86_64")
url="http://ladish.org/"
license=("GPL")
depends=("jackdbus" "dbus-python" "flowcanvas>=0.6.4" "flowcanvas<1.0.0" "hicolor-icon-theme")
makedepends=("git" "python2")
optdepends=("laditools: configure JACK through gladish with ladiconf"
            "a2jmidid: use legacy applications with alsa_seq_midi ports")
install="${pkgname}.install"
source=("${pkgname}.install")
sha256sums=("34e37af9c5aec2623e446b72824cfc503b654a2ee8a6c4d50096fe27c79165bd")

_gitroot="git://repo.or.cz/${pkgname/-/.}"
_gitname="$_pkg"

build() {
  local _gitdir="${srcdir}/${_gitname}"
  msg "Connecting to GIT server...."

  if [[ -d "$_gitdir" ]]; then
    cd "$_gitdir" && git pull origin
    msg "The local files are updated."
  else
    git clone "$_gitroot" "$_gitdir"
  fi

  msg "GIT checkout done or server timeout"
  msg "Starting build..."

  cd "$_gitdir"
  git clean -dfx
  git reset --hard HEAD

  #
  # BUILD
  #

  # use python2
  export PYTHON="/usr/bin/python2"

  # fix the hashbang
  sed -i 's|env python|&2|' "${_pkg}_control"

  # '-Werror' is enabled by default
  # release builds (RELEASE=True) disable '-Werror'
  sed -i "s|\(RELEASE\s*=\s*\).*|\1True|" wscript

  python2 ./waf configure --prefix="/usr" \
                          --enable-liblash \
                          --enable-pylash
  python2 ./waf build
}

package() {
  local _gitdir="${srcdir}/${_gitname}"
  . <(sed -n "s|^VERSION\s*=\s*'\([.0-9]\{1,\}\).*'$|_${_pkg^^}_VERSION=\1|p" "${_gitdir}/wscript")
  provides=("${_pkg}=${_LADISH_VERSION}" "lash")
  conflicts=("${_pkg}" "lash")

  cd "$_gitdir"
  python2 ./waf install --destdir="$pkgdir"
}

# vim:set ts=2 sw=2 et: